怎么重命名大批量的word文档

Question

我下载了一百多个word，但下载下来的文件命都是数字，不是原来的名字了，怎么让它们自动重命名成原来的名字或者是文档开头的几个字也行。

Answer 1

1.首先从电脑上下载2345好压，下载后安装。

2.安装完成后，双击好压快捷图标，弹出好压主界面。

3.点击中间上面的工具箱，看见没，批量文件改名。

4.从上到下，看箭头，想改啥名字怎样改。

5.举个例子。

Answer 2

　　重命名大批量的word文档：

　　要批量重名文件，如果不要求这么复杂的文件名，倒是可以简单的批量重命名。

　　ctrl+A，全选所有文件（或者你自己选中需要的文件），

　　然后右键菜单，选择“重命名”，

　　只有一个文件显示可输入重命名状态，其他文件只是依旧是选中状态。

　　输入新命名，比如“旅行”，回车或者随便鼠标点一下别处。

　　这时候，选中的文件就会自动更名为旅行（1）、旅行（2）、旅行（3）、旅行（4）···········以此类推。

　　一般会自动按照不同类型文件分组更名。

　　比如选中的文件里面有word、rar、excel、txt等格式的文件，那么同时选中后按照以上方法重名后，就会自动分组重命名为：

　　word格式的：旅行（1）、旅行（2）、旅行（3）、旅行（4）···········

　　rar格式的：旅行（1）、旅行（2）、旅行（3）、旅行（4）···········

　　excel格式的：旅行（1）、旅行（2）、旅行（3）、旅行（4）···········

　　所以如果是想要命名不同的，请分类型批量选中。

　　如果更改的新命名复杂的，就没办法了，只能手动了。

Answer 3

可以用脚本来做。

1、用记事本新建一个文本文件，把它保存为“批量重命名.vbs”（注意不要弄成了“批量重命名.vbs.txt”，也就是要确保其扩展名为“.vbs”）；

2、把下列代码粘贴到这个VBS文件中：
Option Explicit

Const g_strRootPath = "c:\Temp\docs\Word\ToRename\" ' 指定存放所有文件的目录，可以有子目录
Const g_nTitleMaxLen = 16 ' 指定获取文档里面第一段中的前多少个字符来作为文件名

Call Main

' 主函数入口
Sub Main()

Dim fso, oFolder, oWordApp

Set oWordApp = CreateObject("Word.Application")
Set fso = CreateObject("Scripting.FileSystemObject")
Set oFolder = fso.GetFolder(g_strRootPath)

RenameDocFilesUnderFolder oWordApp, fso, oFolder

oWordApp.Quit
Set oWordApp = Nothing

MsgBox "完成！"

End Sub

' 重命名指定文件夹（递归）下面的所有Word文件，按照文件里面的第一句可见的文字命名
Sub RenameDocFilesUnderFolder(oWordApp, fso, oFolder)

Dim oSubFolder, oFile, oDoc
Dim strTitle, strFileName

For Each oSubFolder In oFolder.SubFolders
RenameDocFilesUnderFolder oWordApp, fso, oSubFolder
Next

For Each oFile In oFolder.Files
Set oDoc = oWordApp.Documents.Open(oFile.Path)
strTitle = GetFirstVisibleTextContent(oDoc)
oDoc.Close
Set oDoc = Nothing

If Len(strTitle) <> 0 Then
strFileName = fso.BuildPath(fso.GetParentFolderName(oFile.Path), strTitle & "." & fso.GetExtensionName(oFile.Path))
strFileName = GetUniqueFileName(fso, strFileName)
fso.MoveFile oFile.Path, strFileName
End If
Next

End Sub

' 获取指定文档第一行可见文字
Function GetFirstVisibleTextContent(oDoc)

Dim oParagraph
Dim strContent

For Each oParagraph In oDoc.Paragraphs
strContent = GetSafeFileName(oParagraph.Range.Text)
If Len(strContent) <> 0 Then
GetFirstVisibleTextContent = strContent
Exit Function
End If
Next

GetFirstVisibleTextContent = ""

End Function

' 过滤文件名里面的无效字符
Function GetSafeFileName(strFileName)

Dim arrUnsafeCharacters, strUnsafeChar
Dim nIndex

arrUnsafeCharacters = Array("\", "/", ":", "*", "?", """", "<", ">", "|")

For nIndex = 0 To &H2F
strFileName = Replace(strFileName, Chr(nIndex), "")
Next

For Each strUnsafeChar In arrUnsafeCharacters
strFileName = Replace(strFileName, strUnsafeChar, "")
Next

GetSafeFileName = Left(Trim(strFileName), g_nTitleMaxLen)

End Function

' 获取不重复的文件名，如果有重名则在文件名后面附加“_1”、“_2”……
Function GetUniqueFileName(fso, strFullName)

Dim strParentFolder, strBaseName, strExtensionName
Dim nIndex

If Not fso.FileExists(strFullName) Then
GetUniqueFileName = strFullName
Exit Function
End If

strParentFolder = fso.GetParentFolderName(strFullName)
strBaseName = fso.GetBaseName(strFullName)
strExtensionName = fso.GetExtensionName(strFullName)

nIndex = 0

While fso.FileExists(strFullName)
nIndex = nIndex + 1
strFullName = fso.BuildPath(strParentFolder, strBaseName & "_" & nIndex & "." & strExtensionName)
Wend

GetUniqueFileName = strFullName

End Function

3、修改代码中开始部分的两个设置，即：存放等待重命名的Word文件的根目录，以及获取文档第一段内容时最多保留多少个字符。

4、保存这个VBS文件，在资源管理器中双击运行它，直到看见“完成”！

5、检查所有文件是否已自动重命名。

注意：如果有两个以上的文档依据其内容提取出来的文字相同，则会自动在文件名后面附加“_1”、“_2”、“_3”……。

如果有什么问题，请和我联系。

Answer 4

要是想改成像文档1、文档2……这样有序列的可以通过一些批量重命名软件来进行，要想重命名成文档开头的内容的话有点难

Answer 5

这个问题我为其它朋友解答过，请参考这个答案：
http://zhidao.baidu.com/question/162828108.html本回答被提问者采纳